Statistik (6) ->

Kombinatorik: Permutationen mit/ohne Wiederholung (91)
Aufgabe
Wie viel unterschiedliche Reihenfolgen können aus einem Text gebildet werden,
in dem der selbe Buchstabe mehrfach vorkommen kann ?

       A               B               C               D               E               F               G               H       
1 abcdefagab    a  302400    Beispiele  Anzahl  Formel  
2     b      ABAC  12  =4!/2!  
3     c      AAABBB  20  =6!/(3!*3!)  
4     d      AAABBCCDEF  151200  =10!/(3!*2!*2!)  
5     e           
6     f      Beispiel 1:  ABAC   
7     a        AABC   
8     g        ABCA   
9     a        BAAC   
10     b        BACA   
11             BCAA   
12             ACAB   
13             AACB   
14             ACBA   
15             CAAB   
16             CABA   
17             CBAA   



Lösung
In A1 steht der Text

Hilfsspaltenlösung:

Schreibe in C1
=WENN(ZEILE()>LÄNGE($A$1);"";TEIL($A$1;ZEILE();1))
und kopiere dies bis C100, Text kann maximal 100 Zeichen haben.

in D1 steht die Anzahl Permutationen:
{=FAKULTÄT(LÄNGE(A1))/PRODUKT(FAKULTÄT(WENN((ZÄHLENWENN(INDIREKT("C1:C"&ZEILE(1:100));C1:C100))*(C1:C100<>"")=1;ZÄHLENWENN(C1:C100;C1:C100);1)))}

Lösung mit Namen (ohne Hilfsspalte):

vergebe folgende Namen
Name:ix
bezieht sich auf:=ZEILE(INDIREKT("1:"&LÄNGE(Tabelle1!$A$1)))
Name:Feld
bezieht sich auf:=TEIL(Tabelle1!$A$1;ix;1)

Anzahl Permutationen mit Wiederholungen:
{=FAKULTÄT(LÄNGE($A$1))/PRODUKT(FAKULTÄT(WENN(VERGLEICH(Feld;Feld;0)=ix;MMULT((Feld=MTRANS(Feld))*1;WENN(ix;1));1)))}

Anzahl Permutationen ohne Wiederholung ergeben sich aus
=Fakultät(Länge(A1))
Erläuterung
MMULT zÄhlt, wie oft jedes Zeichen im Text vorkommt. Mit ZÄHLENWENN ist das nur in einem Bereich möglich.



zurück


gestaltet by Biene Maya