Listen/Datensätze (10) ->

Werte aus Spalte herausfiltern (Autofilter per Formel) (89)
Aufgabe
Du willst eine neue Liste erstellen, in denen bestimmte Werte der Ursprungsliste nicht mehr enthalten sind.

       A               B       
1 Liste   gefiltert  
2 1   1  
3 2   2  
4 3   3  
5 8   4  
6 4   9  
7 5   7  
8 9   3  
9 7   9  
10 5   10  
11 3   11  
12 8   �  
13 9   �  
14 10   �  
15 11   �  
16 5   � 

Lösung
alte Liste in Spalte: A
neue Liste in Spalte: B
herauszufilternde Werte: 5 und 8

In B2 steht:
{=INDEX(A$1:A$99;KKLEINSTE(WENN((A$1:A$99<>5)*(A$1:A$99<>8);ZEILE($1:$99));ZEILE()))}
und runterkopieren

Sollen umgekehrt nur die Fünfer und Achter aufgelistet werden, dann in B2:
{=INDEX(A$1:A$99;KKLEINSTE(WENN((A$1:A$99=5)+(A$1:A$99=8);ZEILE($1:$99));ZEILE(A1)))}

Ohne Fehlermeldung, wenn keine mehr auftauchen:
{=WENN(ZEILE(A1)>SUMME(ZÄHLENWENN(A$1:A$99;{5;8}));"";INDEX(A$1:A$99;KKLEINSTE(WENN((A$1:A$99=5)+(A$1:A$99=8);ZEILE($1:$99));ZEILE(A1))))}

Der "Normalfall" (ein Suchkriterium)
in A1 bis A999 steht ne Liste
in E1 steht der Suchbegriff (auch Teile davon)
{=WENN(ZÄHLENWENN(A:A;"*"&E$1&"*") < ZEILE(A1);"";INDEX(A$1:A$999; KKLEINSTE(WENN(ISTZAHL(SUCHEN(E$1;A$1:A$999));ZEILE($1:$999));ZEILE(A1))))}

Erläuterung
Eine Formellösung statt des Autofilters/Spezialfilters hat den granatenmäßigen Vorteil, dass Sie sich Änderungen anpasst. Der "normale" Filter müßte ja jedesmal neu bestückt/ausgeführt werden.


zurück


gestaltet by Biene Maya