Listen/Datensätze (10) ->

Zahlenfolge mit Lücken linear auffüllen (465)
Aufgabe
In Spalte A steht eine lückenhafte (Leerzellen) Zahlenfolge. Diese Leerzellen sollen - abhängig vom letzten und folgenden Wert - linear aufgefüllt werden.

       A               B       
1 -16  -16  
2 -15,3  -15,3  
3   -13,86666667  
4   -12,43333333  
5 -11  -11  
6   -4,833333333  
7   1,333333333  
8 7,5  7,5  
9   7,75  
10 8  8  
11   4,75  
12   1,5  
13   -1,75  
14 -5  -5  
15   #ZAHL!  
16   #ZAHL! 


Lösung
In B1 steht:
=A1

in B2 steht:
{=WENN(A2="";B1+(INDEX(A:A;MIN(WENN(A2:A$99<>"";ZEILE(A2:A$99))))-INDEX(A:A;MAX(WENN(A$1:A2<>"";ZEILE(A$1:A2)))))/(MIN(WENN(A2:A$99<>"";ZEILE(A2:A$99)))-MAX(WENN(A$1:A2<>"";ZEILE(A$1:A2))));A2)}
runterkopieren

Endet die Liste in Spalte A, erfolgt danach #ZAHL!

Ist ja gut - ohne diese Fehlermeldung in B2 also:
{=WENN(ANZAHL(A2:A$9999)=0;"";WENN(A2="";B1+(INDEX(A:A;MIN(WENN(A2:A$99<>"";ZEILE(A2:A$99))))-INDEX(A:A;MAX(WENN(A$1:A2<>"";ZEILE(A$1:A2)))))/(MIN(WENN(A2:A$99<>"";ZEILE(A2:A$99)))-MAX(WENN(A$1:A2<>"";ZEILE(A$1:A2))));A2))}

zurück


gestaltet by Biene Maya