Statistik (6) ->

alle möglichen Zweier eines(r) beliebig langen Textes(Zahl) auflisten (448)
Aufgabe
Der screenshot ist selbsterklärend.

       A               B               C               D               E               F               G               H               I       
1 469  46  1  2    Boris  bo  1  2  
2   49  1  3      br  1  3  
3   64  2  1      bi  1  4  
4   69  2  3      bs  1  5  
5   94  3  1      ob  2  1  
6   96  3  2      or  2  3  
7             oi  2  4  
8             os  2  5  
9             rb  3  1  
10             ro  3  2  
11             ri  3  4  
12             rs  3  5  
13             ib  4  1  
14             io  4  2  
15             ir  4  3  
16             is  4  5  
17             sb  5  1  
18             so  5  2  
19             sr  5  3  
20             si  5  4 



Lösung
in A1 steht der Text/die Zahl
in C1 steht 1 und in D1 steht 2

In B1 steht:
=WENN(C1="";"";KLEIN(TEIL(A$1;C1;1)&TEIL(A$1;D1;1)))

in C2 steht:
=WENN(ZEILEN($1:2)>VARIATIONEN(LÄNGE(A$1);2);"";WENN(ZÄHLENWENN(C$1:C1;C1)=LÄNGE(A$1)-1;C1+1;C1))

in D2 steht:
=WENN(C2="";"";WENN(C2 <> C1;1;D1+1+((D1+1)=C1)))

B1, C2 und D2 ausreichend weit runterkopieren
Die Spalten C und D (Hilfsspalten) dann ausblenden.

Die Anzahl geordneter Variationen ohne Wiederholung ergibt sich aus:
=VARIATIONEN(LÄNGE(A1);2)
=KOMBINATIONEN(LÄNGE(A1);2)*2

Sollen bei Zahlen / Texten mit mehreren gleichen Ziffern / Buchstaben (4847 / Trixi) keine Duplikate aufgeführt werden, dann ab E1 unsere Formel Nr. 194 (Listen Datensätze):
in E1 steht: =B1
in E2 steht:
{=WENN(SUMME(ZÄHLENWENN(B$1:B$99;E$1:E1))>=SUMME((B$1:B$99<>"")*1);"";INDEX(B:B;VERGLEICH(1;1*(ZÄHLENWENN(E$1:E1;B$1:B$100)=0);0)))}
Hilfsspalten B, C und D dann ausblenden.


zurück